home *** CD-ROM | disk | FTP | other *** search
/ Suzy B Software 2 / Suzy B Software CD-ROM 2 (1994).iso / new_file / programm / a56 / a56.lzh / examples / reverb.a56 < prev    next >
Encoding:
Text File  |  1994-09-02  |  7.5 KB  |  312 lines
  1. ;***************************************************************
  2. ; 
  3. ; A stereo reverb for the DSP56001 signal processor.
  4. ; Developed by Quinn Jensen (jensenq@qcj.icon.com) using
  5. ; Dr. Vercoe and company's csound code as a reference for the 
  6. ; configuration and gain values.
  7. ; 
  8. ;     NOTE - A much improved reverb algorithm is in sixcomb.a56
  9. ; 
  10. ; This program fragment implements a stereo reberb effect
  11. ; on a DSP56001 processor.  The "depth" and wet/dry mix are
  12. ; adjustable.  The following filter configuration is employed:
  13. ;
  14. ;
  15. ;  Left in ------+------- "dry" gain -----------> sum -----> Left out
  16. ;                |                                 ^
  17. ;                v                                 |
  18. ;               sum --> reverb --> "wet" gain -----+
  19. ;                ^                                 |
  20. ;                |                                 v -
  21. ;  Right in -----+------- "dry" gain -----------> sum -----> Right out
  22. ;
  23. ;
  24. ; Note that the reverb path output is negated before summing with the
  25. ; right input signal.  This throws in 180 degrees of phase shift
  26. ; making for interesting results even with mono inputs 
  27. ; (i.e. Left in == Right in).
  28. ; 
  29. ; The reverb element looks like this:
  30. ;
  31. ;
  32. ; Input ----+-----> comb1 ------+
  33. ;           |                   |
  34. ;           +-----> comb2 ---\  v
  35. ;           |                  sum -----> allpass1 --> allpass2 ---> output
  36. ;           +-----> comb3 ---/  ^
  37. ;           |                   |
  38. ;           +-----> comb4 ------+
  39. ;
  40. ; Each comb stage looks like this:
  41. ;
  42. ;                        +---- gain <-----+
  43. ;                        |                |
  44. ;                        v                |
  45. ; Input ---> gain ----> sum ---> delay ---+--> out
  46. ;
  47. ;
  48. ; The allpass stages look like:
  49. ;
  50. ;                         +--------- gain <---------+
  51. ;                         |                         |
  52. ;                         v                         |
  53. ; Input ---> gain --+--> sum ---> delay ---> sum ---+----> out
  54. ;                   |                         ^
  55. ;                   |                         |
  56. ;                   +--------> gain ----------+
  57. ;
  58. ; or,
  59. ;
  60. ;                             +-------> gain ----+
  61. ;                             |                  |
  62. ;                             |                  v
  63. ; Input ---> gain ----> sum --+--> delay --+--> sum -----> out
  64. ;                        ^                 |
  65. ;                        |                 |
  66. ;                        +----- gain <-----+
  67. ;
  68. ;
  69. ; I've seen both configurations in the literature, so I plotted the
  70. ; Z-transform and they are equivalent in the steady state.  They are indeed
  71. ; all-pass in the steady state but are supposed to have a subtle, discernable
  72. ; effect in "transient" audio signals.
  73. ;
  74. ; I think it could really use a couple more comb stages to fill in some of the 
  75. ; graininess.  The best possible "diffusion" is desired.  By the way, 
  76. ; I'd enjoy seeing any optimizations to the code.
  77. ;
  78.  
  79. ;hardware specific initialization code
  80.  
  81. include "tdsg.a56"
  82.  
  83. ;***************************************************************
  84. ;
  85. ;    Data and constants
  86. ;
  87. ;***************************************************************
  88.  
  89. dot                ;remember where we were in P-space
  90.     org    x:$10        ;put runtime variables in on-chip X-space
  91.  
  92. ; A spreadsheet was used to calculate the following numbers
  93. ;
  94. ; The gain of each feedback stage is given by
  95. ;
  96. ;    feedback gain = exp(delay * ln(.001)/duration)
  97. ;
  98. ; where "delay" is the delay of the comb or allpass stage in seconds,
  99. ; and "duration" is the time in seconds for the reverberated sound
  100. ; to decay to 1/1000 of its original amplitude.
  101. ;
  102.  
  103. ;  Reverb filter lengths and coefficients  
  104. ;  Sun Aug  4 16:36:16 1991    
  105. ;  
  106. ;      Sample rate               32.5520830 kHz      
  107. ;      Reverb duration            4.0000000 s        
  108. ;  
  109. ;  stage    delay(ms)    length        gain    actual
  110. ;  -----------------------------------------------------       
  111. ;  Comb1   29.7000000       967   0.9500031     29.71
  112. ;  Comb2   37.1000000      1208   0.9379399     37.11
  113. ;  Comb3   41.1000000      1338   0.9314831     41.10
  114. ;  Comb4   43.7000000      1423   0.9273101     43.71
  115. ;  All-1    5.0000000       163   0.9914025      5.01
  116. ;  All-2    1.7000000        55   0.9970685      1.69
  117.  
  118. in_atten equ                      0.3409091
  119. comb_atten equ                    0.0416667
  120. dry_init equ                      0.4000000    ; initial "dry" gain
  121. reverb_init equ                0.9900000    ; initial "wet" gain
  122.  
  123. ; comb 1 data and parameters
  124.  
  125. c1d equ                   $4000
  126. c1r  dc                     c1d
  127. c1m equ                     966
  128. c1c equ                           0.9500031
  129.  
  130. ; comb 2 data and parameters
  131.  
  132. c2d equ          c1d+      2048
  133. c2r  dc                     c2d
  134. c2m equ                    1207
  135. c2c equ                           0.9379399
  136.  
  137. ; comb 3 data and parameters
  138.  
  139. c3d equ          c2d+      2048
  140. c3r  dc                     c3d
  141. c3m equ                    1337
  142. c3c equ                           0.9314831
  143.  
  144. ; comb 4 data and parameters
  145.  
  146. c4d equ          c3d+      2048
  147. c4r  dc                     c4d
  148. c4m equ                    1422
  149. c4c equ                           0.9273101
  150.  
  151. ; allpass 1 data and parameters
  152.  
  153. a1d equ          c4d+      2048
  154. a1r  dc                     a1d
  155. a1m equ                     162
  156. a1c equ                           0.9914025
  157.  
  158. ; allpass 2 data and parameters
  159.  
  160. a2d equ          a1d+      2048
  161. a2r  dc                     a2d
  162. a2m equ                      54
  163. a2c equ                           0.9970685
  164.  
  165.     org    y:$0
  166.  
  167. reverb_on equ    reverb_init
  168. reverb_off equ    0
  169.  
  170. reverb_gain
  171.     dc    reverb_on
  172. dry_gain
  173.     dc    dry_init
  174.  
  175.     org    p:dot        ;go back to P-space
  176.  
  177. ;*****************************************************
  178. ;
  179. ; reverb initialization code
  180. ;
  181. ;*****************************************************
  182.  
  183. hf_init
  184.     rts
  185.  
  186. ;*****************************************************
  187. ;
  188. ; run-time controls
  189. ;
  190. ;*****************************************************
  191.  
  192. eff1_on        ;enable reverb
  193.     move            #reverb_on,y0
  194.     move            y0,y:<reverb_gain
  195.     rts
  196.  
  197. eff1_off    ;bypass reverb
  198.     move            #reverb_off,y0
  199.     move            y0,y:<reverb_gain
  200.     rts
  201.  
  202. ;*****************************************************
  203. ;
  204. ; interrupt time calculations
  205. ;
  206. ;*****************************************************
  207.  
  208. ;
  209. ; fs = 32.552083 kHz
  210. ;
  211.  
  212. hf_comp
  213.     jsr    <saveregs
  214. ;
  215. ;    L/R mix
  216. ;
  217.     clr    a    #in_atten,x1        ;clr a, get scale for mix
  218.     move        x:<in_l,x0        ;get left in
  219.     move        x0,x:<in_ls        ;save
  220.     macr    x0,x1,a x:<in_r,x0        ;a = scale * left, get right
  221.     macr    x0,x1,a    x0,x:<in_rs        ;a += scale * right, save right
  222.     clr    b        a,y0        ;y0 goes to the combs, b is sum
  223. ;
  224. ;    comb 1 
  225. ;
  226.     move        x:<c1r,r0
  227.     movec        #c1m,m0
  228.     move            y0,a
  229.     move        x:(r0),x1
  230.     add    x1,b    #c1c,x0
  231.     macr    x0,x1,a
  232.     move        a,x:(r0)+
  233.     move        r0,x:<c1r
  234. ;
  235. ;    comb 2
  236. ;
  237.     move        x:<c2r,r0
  238.     movec        #c2m,m0
  239.     move            y0,a
  240.     move        x:(r0),x1
  241.     add    x1,b    #c2c,x0
  242.     macr    x0,x1,a
  243.     move        a,x:(r0)+
  244.     move        r0,x:<c2r
  245. ;
  246. ;    comb 3
  247. ;
  248.     move        x:<c3r,r0
  249.     movec        #c3m,m0
  250.     move            y0,a
  251.     move        x:(r0),x1
  252.     add    x1,b    #c3c,x0
  253.     macr    x0,x1,a
  254.     move        a,x:(r0)+
  255.     move        r0,x:<c3r
  256. ;
  257. ;    comb 4
  258. ;
  259.     move        x:<c4r,r0
  260.     movec        #c4m,m0
  261.     move            y0,a
  262.     move        x:(r0),x1
  263.     add    x1,b    #c4c,x0
  264.     macr    x0,x1,a
  265.     move        a,x:(r0)+
  266.     move        r0,x:<c4r
  267. ;
  268. ;    scale
  269. ;
  270.     move        #comb_atten,x0    b,y0
  271.     mpyr    x0,y0,b
  272.  
  273. ;
  274. ;    allpass 1
  275. ;
  276.     move        x:<a1r,r0
  277.     movec        #a1m,m0
  278.     move        #a1c,x0
  279.     move        x:(r0),x1
  280.     macr    x0,x1,b    x1,a
  281.     move            b,y0
  282.     macr    -x0,y0,a b,x:(r0)+
  283.     move        r0,x:<a1r
  284. ;
  285. ;    allpass 2
  286. ;
  287.     move        x:<a2r,r0
  288.     movec        #a2m,m0
  289.     move        #a2c,x0
  290.     move        x:(r0),x1
  291.     macr    x0,x1,a    x1,b
  292.     move            a,y0
  293.     macr    -x0,y0,b a,x:(r0)+
  294.     move        r0,x:<a2r
  295. ;
  296. ;    output mix
  297. ;
  298.     move        b,x0
  299.     move            y:<reverb_gain,y0
  300.     mpyr    x0,y0,b        y:<dry_gain,y0
  301.     move        x:<in_ls,x0
  302.     move        b,a
  303.     macr    x0,y0,a    x:<in_rs,x0
  304.     macr    x0,y0,b    a,x:<out_l
  305.     move        b,x:<out_r
  306.  
  307.     jsr    <restregs
  308.     rts
  309.  
  310.     end
  311.  
  312.